s i l r u n   S y s t e m s
Commodore Amiga / Casio & Sharp Pocket Computer

16
Divisionen
Casio fx-880

(c) silrun Systems 29.07.1994
Malte Brockmann
Im Loffenkamp 4 * 31832 Eldagsen
Postfach 3027 * 31821 Eldagsen


Die Programmteile sind einzeln lauffähig. Sie erwarten als erstes den Zähler, dann den Nenner.

1 '(c) silrun Systems 19.01.1992   16: Divisionen

101 '(c) silrun Systems 1992        16a: Divisionsrest v2.0
110 CLS:PRINT"Divisionsrest":CLEAR
115 CLS:LOCATE1,0:INPUT@10;z$:z=VAL(z$):IFz=0THEN115
120 CLS:PRINTz;CHR$(159)" ";:INPUT@10;n$:n=VAL(n$):IFn=0THEN120
125 LOCATE0,1:PRINTINT(z/n)"Rest"z-n*INT(z/n):GOTO115

201 '(c) silrun Systems 1992        16b: Bruchdarstellung v2.0
210 CLS:PRINT"Bruchdarstellung":CLEAR
215 CLS:LOCATE1,0:INPUT@10;z$:z=VAL(z$):IFz=0THEN215
220 CLS:PRINTz;CHR$(159)" ";:INPUT@10;n$:n=VAL(n$):IFn=0THEN220
225 z=ROUND(z,-1):n=ROUND(n,-1):z1=ABSz:n1=ABSn
230 IFz1>n1 THENc=z1:z1=n1:n1=c
235 c=-(INT(z1/n1)*n1-z1):IFc<>0THENz1=n1:n1=c:GOTO235
240 z2=z/n1:n2=n/n1:IFn2<0THENn2=ABSn2:z2=-z2
245 LOCATE0,1:PRINTz2;CHR$(159)n2"=";ROUND(z2/n2,-4):GOTO215

301 '(c) silrun Systems 1992        16c: Superdivision v4.0
310 CLS:PRINT"Superdivision":CLEAR
315 CLS:LOCATE1,0:INPUT@10;z$:z=VAL(z$):IFz=0THEN315
320 CLS:PRINTz;CHR$(159)" ";:INPUT@10;n$:n=VAL(n$):IFn=0THEN320
325 LOCATE0,1:INPUT"Genauigkeit ? ";@3;g$:g=VAL(g$):IFg<=0 THENg=15
330 LOCATE0,1:PRINTCHR$(5);:LOCATE0,0
335 z=ROUND(z,-8):n=ROUND(n,-8):z1=ABSz:n1=ABSn:q=INT(z1/n1)
340 IFz/n<0THENq=-q
345 LOCATE0,1:PRINTSTR$(q)".";:q=z-n*q
350 FORw=1TOg:e=INT(q*10/n1):PRINTRIGHT$(STR$(e),1);
355 q=10*q-n1*e:IFq<>0THENNEXTw
360 PRINT"":GOTO315

End of File